fillTime = now()
fieldCount = QP.FormFieldCount()
fncDebug("<br>Field Count = " & fieldCount)
'for i = 1 to fieldCount
' fncdebug("<br>" & i & ". UpdateAppearanceStream: " & QP.GetFormFieldTitle(i) & " - result: " & QP.UpdateAppearanceStream(i))
' fncdebug("<br>" & i & ". Readonly to False- Field : " & QP.GetFormFieldTitle(i) & " - result: " & QP.SetFormFieldReadOnly(i,0))
'next

'default to fill fields unless specified as false
if lcase(request("PDF~property~FillFormFields")) <> "false" then
 fncDebug("<hr>Merging posted form data into PDF and setting properties")

 ' Determine of the PDF fields should be marked as readonly.
 ' All fields will default to readonly if there it is not specified at the PDF level,
 ' if PDF~property~FormFieldsReadOnly if not specified or has a blank value, lock the fields
 ' or this can be overridden at the field level using a form element of fieldname~property~readonly with a value of "true" or "false"
 if len(request("PDF~property~FormFieldsReadOnly")) > 0 and instr("false no 0", lcase(request("PDF~property~FormFieldsReadOnly") ) ) > 0 then
  prefilledFormFieldsReadonly = false
 else
  'default position if not specified otherwise
  prefilledFormFieldsReadonly = true
 end if
 fncDebug("<br> - Mark all prefilled form fields READONLY = " & prefilledFormFieldsReadonly )

 for each item in request.form
  'Check if properties need to be set on any form fields
  'Format for form is "fieldname~property~property-type" with a value set to the value of the form element
  'multi value form elements should be delimited with a comma, ie: (0.5,0.5,0.5)to set (color 50%, red 50% green, 50% blue)
  if instr(item,"~property~")>0 then
   select case lcase(split(item,"~")(2))
    case "alignment"
     result =  QP.SetFormFieldAlignment(QP.FindFormFieldByTitle(split(item,"~")(0)),request.form(item))
    case "textsize"
     result =  QP.SetFormFieldTextSize(QP.FindFormFieldByTitle(split(item,"~")(0)),request.form(item))
    case "backgroundcolor"
     result = QP.SetFormFieldBackgroundColor(QP.FindFormFieldByTitle(split(item,"~")(0)),split(request.form(item),",")(0),split(request.form(item),",")(1),split(request.form(item),",")(2))
    case "standardfont"
     result =  QP.SetFormFieldStandardFont(QP.FindFormFieldByTitle(split(item,"~")(0)),request.form(item))
   end select
   fncDebug("<br> - Property Setting <b>" & item & "</b> Datafield <b>" & split(item,"~")(0) & "</b> = <b>" & request.form(item) & "</b>, Results = <b>" & result & "</b>")
  elseif lcase(item) <> "pdfname" then
   'if field exists in the pdf, insert matching data value from posted form
   result = QP.SetFormFieldValue(QP.FindFormFieldByTitle(item),request.form(item))
   fncDebug("<br> - Datafield <b>" & item & "</b> = <b>" & request.form(item) & "</b>, Results = <b>" & result & "</b>")
   'if field is supposed to be marked readonly and the field was populated, secure it
   if prefilledFormFieldsReadonly and result = 1 then
    fncDebug("<br> - Readonly <b>" & item & "</b>  set = <b>true</b>, Results = <b>" & QP.SetFormFieldReadOnly(QP.FindFormFieldByTitle(item),1) & "</b>")
   end if
  end if
 next
end if
fncDebug("<br>Elapsed Time for Filling fields=" & dateDiff("S",fillTime,now()))